Shader noise example the bookofshaders converted comes with wrong result in Godot v4.3.dev1

Godot Version

v4.3.dev1.official [9d1cbab1c]

Question

I tried to convert this shader noise example and on the Godot, I don’t have the same result link in the web page example
The shader is :

shader_type canvas_item;

uniform vec2 u_resolution;
uniform vec2 u_mouse;
uniform float p_time; // this will * TIME in fragment()

float random (vec2 _st) {
    return fract(sin(dot(_st.xy, vec2(12.9898,78.233)))* 43758.5453123);
}

float noise (vec2 _st) {
    vec2 i = floor(_st);
    vec2 f = fract(_st);

    float a = random(i);
    float b = random(i + vec2(1.0, 0.0));
    float c = random(i + vec2(0.0, 1.0));
    float d = random(i + vec2(1.0, 1.0));

    vec2 u = f * f * (3.0 - 2.0 * f);

    return mix(a, b, u.x) + (c - a)* u.y * (1.0 - u.x) + (d - b) * u.x * u.y;
}

#define NUM_OCTAVES 5

float fbm (vec2 _st) {
    float v = 0.0;
    float a = 0.5;
    vec2 shift = vec2(100.0);
	vec2 aa = vec2(cos(0.5), sin(0.5));
	vec2 bb = vec2(sin(0.5), cos(0.50));
    mat2 rot = mat2(aa, bb);
    for (int i = 0; i < NUM_OCTAVES; ++i) {
        v += a * noise(_st);
        _st = rot * _st * 2.0 + shift;
        a *= 0.5;
    }
    return v;
}

void fragment() {
    vec2 st = SCREEN_UV * 3.0;
    vec3 color = vec3(0.0);
	float u_time = p_time * TIME;
    vec2 q = vec2(0.0);
    q.x = fbm(st + 0.00*u_time);
    q.y = fbm(st + vec2(1.0));

    vec2 r = vec2(0.0);
    r.x = fbm(st + 1.0*q + vec2(1.7,9.2)+ 0.15*u_time);
    r.y = fbm(st + 1.0*q + vec2(8.3,2.8)+ 0.126*u_time);

    float f = fbm(st+r);

    color = mix(vec3(0.101961,0.619608,0.666667), vec3(0.666667,0.666667,0.498039), clamp((f*f)*4.0,0.0,1.0));

    color = mix(color, vec3(0,0,0.164706), clamp(length(q),0.0,1.0));

    color = mix(color, vec3(0.666667,1,1), clamp(length(r.x),0.0,1.0));

    COLOR = vec4((f*f*f + 0.6*f*f + 0.5*f) * color, 1.0);
}

This is the result of the shader:

You shouldn’t use SCREEN_UV when not sampling the entire screen. Instead set st to UV*3.0. Furthermore u_time is just TIME in Godot.
Take a look here: Converting GLSL to Godot shaders — Godot Engine (stable) documentation in English

2 Likes

I am looking at this and I have no clue why there’s that artifact in the output. The code is identical. (you missed a sign on bb, if should be -sin, but it doesn’t change much)
I can’t offer an explanation, but I can tell you it is not you doing something wrong, I don’t think.

A bit of testing tells me maybe the 43758.5453123 factor is way too big for some reason.

Further testing implies the fault is somewhere around the b c d factors in the noise function.

1 Like

I used Artificial Intelligence Assistant - ARIA to convert the source code for that shader and I don’t see these diff.
… fixed, that sign of sin, multiplication, and SCREEN_UV, works better with UV :

shader_type canvas_item;

uniform vec2 u_resolution;
uniform vec2 u_mouse;
uniform float p_time; // this will * TIME in fragment()

float random (vec2 _st) {
    return fract(sin(dot(_st.xy, vec2(1.29898,7.8233)))* 4.37585453123);
}

float noise (vec2 _st) {
    vec2 i = floor(_st);
    vec2 f = fract(_st);

    float a = random(i);
    float b = random(i + vec2(1.0, 0.0));
    float c = random(i + vec2(0.0, 1.0));
    float d = random(i + vec2(1.0, 1.0));

    vec2 u = f * f * (3.0 - 2.0 * f);

    return mix(a, b, u.x) + (c - a)* u.y * (1.0 - u.x) + (d - b) * u.x * u.y;
}

#define NUM_OCTAVES 5

float fbm (vec2 _st) {
    float v = 0.0;
    float a = 0.5;
    vec2 shift = vec2(100.0);
	vec2 aa = vec2(cos(0.5), sin(0.5));
	vec2 bb = vec2(-sin(0.5), cos(0.50));
    mat2 rot = mat2(aa, bb);
    for (int i = 0; i < NUM_OCTAVES; ++i) {
        v += a * noise(_st);
        _st = rot * _st * 2.0 + shift;
        a *= 0.5;
    }
    return v;
}

void fragment() {
    vec2 st = UV * 1.14;
	//vec2 st = SCREEN_UV * 1.14;
    vec3 color = vec3(0.0);
	float u_time = p_time * TIME;
    vec2 q = vec2(0.0);
    q.x = fbm(st + 0.00*u_time);
    q.y = fbm(st + vec2(1.0));

    vec2 r = vec2(0.0);
    r.x = fbm(st + 1.0*q + vec2(1.7,9.2)+ 0.15*u_time);
    r.y = fbm(st + 1.0*q + vec2(8.3,2.8)+ 0.126*u_time);

    float f = fbm(st+r);

    color = mix(vec3(0.101961,0.619608,0.666667), vec3(0.666667,0.666667,0.498039), clamp((f*f)*4.0,0.0,1.0));

    color = mix(color, vec3(0,0,0.164706), clamp(length(q),0.0,1.0));

    color = mix(color, vec3(0.666667,1,1), clamp(length(r.x),0.0,1.0));

    COLOR = vec4((f*f*f + 0.6*f*f + 0.5*f) * color, 1.0);
}

image

1 Like